Windows Server 2008 mapped drives not showing on workstations?

I am running Windows Server 2008 Standard Edition with a Windows XP Pro workstation setup as a test unit.

I have added an Organisational Unit called 'Misc Users' and have linked a GP called 'Basic Security GP' to the OU. Any changes I make to the GP are almost immediately reflected on the workstation. I have removed the control panel, run and setup roaming profiles which map successfully from the H drive to my share on the server.

I want to add another mapped drive as a test. I have created a simple share on the server which is:

\\server\miscusers

So I have edited the GP and added a mapped drive with the following settings:

Action: create
Location \\server\miscusers
Reconnect: No
Label As: Misc Users
Use: O
Show this drive is selected

but the mapped drive never shows up for my user.

Is there any reason for this? I have prevented the A, C and D drive from being shown in My Computer but as this drive is O it should work.

Thanks,
Danny

From serverfault dannymcc

• If you're using Preferences, most of them only work under Vista and Win7. Preferences will not work at all on XP unless you have the XP CSE installed. And most of them only work most of the time. Many SysAdmins avoid Preferences like the plague.

  Edit:
  Here's a copy of the MapDrives.vbs script we use. Works flawlessly on WinXP/Vista/7/2003/2008/R2.

  ' Author: Chris Stone
  ' Date: 29 MAY 2009  Version: 1.3
  ' Purpose: Map network drives
  
  On Error Resume Next
  Set objNet = CreateObject("WScript.Network")
  
  Public Sub CheckAndMapNetDrive(Letter, Path, Persist)
      'Check if drive letter is already used
      Set colNetDrives = objNet.EnumNetworkDrives
      For i = 0 To colNetDrives.Count - 1 Step 2
          If colNetDrives.Item(i) = Letter Then
              'Drive Letter Exists, Test if it's the same Path
              If colNetDrives.Item(i+1) = Path Then
                  'It's the same, no new mapping necessary.
                  Exit Sub
              Else
                  'It's different, remove old.
                  objNet.RemoveNetworkDrive colNetDrives.Item(i)
              End If
          End If
      Next
      'Drive does not exist now, never did or removed.
      objNet.MapNetworkDrive Letter, Path, Persist
  End Sub 
  
  CheckAndMapNetDrive "X:", "\\server\share1", True
  CheckAndMapNetDrive "Y:", "\\server\share2", True
  

  dannymcc : Thanks for the link, I'll try that first thing tomorrow. Is there an alternative to preferences?

  Chris S : The policies section has settings for most things (mapped drives aren't in there, but you can write a quick script to map the drives, and scripts are in Policies). The Preferences section was developed by a company MS bought, and MS has never done much with it.

  dannymcc : Ok, I'll try and find a decent tutorial on scripts in that case then. Thanks!

  Chris S : @Dannymcc, I edited in the script we use here. See above.

  dannymcc : Thanks, I'm viewing this page on my iPhone so I may not be seeing the whole script - where would I specify the network share location?

  Chris S : @Dannymcc, The very bottom has two examples where X: and Y: are mapped to share1 and share2 respectively. Just mess with the drive letter and path until it fits your needs, you can add more lines (or take away) as necessary.

  dannymcc : Ahh, I see. I couldn't see those two line on my phone. So I alter the locations and put this script into the GP using the logon script property? I'll give this a go and see how I get on. Thanks a million.
  From Chris S